Developing Installers for Office:Mac 2016 application add-ins

do shell script "curl -f http://mydomain.com/test.ppam -o " & FolderPathAndFileName

on DownloadAddIn()
	set ADDIN_URL to "http://mydomain.com/test.ppam"
	set ADDIN_FILE to "test.ppam"
	
	-- Set a variable for the Office add-ins folder
	set ADDIN_FOLDER to "~/Library/'Group Containers'/UBF8T346G9.Office/'User Content.localized'/Add-Ins/"
	
	-- Download the add-in component
	do shell script "cURL -f " & ADDIN_URL & " -o " & ADDIN_FOLDER & ADDIN_FILE
end DownloadAddIn

-- Check if the require host can be reached
on IsSystemOnline(HostName)
	repeat with i from 1 to 2
		try
			do shell script "ping -o -t 2 " & HostName
			exit repeat
		on error
			return false
		end try
	end repeat
	return true
end IsSystemOnline

register add in ADDIN_PATH

-- the register command requires a fully qualified path ("~/Library" isn't recognised)
set myAddIn to register add in ADDIN_PATH
-- set the add-in to automatically load each time PowerPoint starts (this triggers HKLM update in pseudo registry)
set the auto load of myAddIn to true
-- load the add-in now
set the loaded of myAddIn to true

on RegisterAddIn(ADDIN_PATH)
	tell application "Microsoft PowerPoint" -- Invokes a PowerPoint instance if not already running
		try
			-- the register command requires a fully qualified path ("~/Library" isn't recognised)
			set myAddIn to register add in ADDIN_PATH
			
			-- set the add-in to automatically load each time PowerPoint starts (this triggers HKLM update in pseudo registry)
			set the auto load of myAddIn to true
			-- load the add-in now
			set the loaded of myAddIn to true
			
			return myAddIn
		on error errorMessage number errorNumber
			display alert "Error Registering Add-In" message errorNumber & return & errorMessage as critical
		end try
	end tell
end RegisterAddIn

-- Attempt to register and load the add-in
set myAddIn to RegisterAddIn(GetHomeFolder() & "/Library/Group Containers/UBF8T346G9.Office/User Content.localized/Add-Ins/" & ADDIN_FILE)

on GetHomeFolder()
	tell application "System Events"
		return POSIX path of (path to home folder) as string
	end tell
end GetHomeFolder

-- If the add-in is Registered, AutoLoad is on and it's Loaded, give user feedback
if fRegistered = true and fAutoLoad = true and fLoaded = true then
	tell application "Microsoft PowerPoint"
		display alert "Success!" message ADDIN_NAME & " for PowerPoint has been installed." & HELP_TIP as informational buttons {"OK"} -- giving up after 3
	end tell
end if

-- Make a add-in specific folder within the Office sandbox for the add-in to use
on MakeDataFolder()
	set fldrOffice to GetHomeFolder() & "/Library/Group Containers/UBF8T346G9.Office"
	do shell script "cd " & quoted form of POSIX path of fldrOffice & "; mkdir -p " & ADDIN_NAME
end MakeDataFolder

--Write the Script file if it does not exist
on CreateScriptsForVBA()
	try
		tell application "Finder" to set targetFolder to (target of the front window) as alias
	on error -- no window
		set targetFolder to (choose folder)
	end try
	
	# build a parameter string from the folder list
	set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, space}
	set {fldrScripts, AppleScript's text item delimiters} to {fldrScripts as text, tempTID}
	
	do shell script "cd " & quoted form of POSIX path of targetFolder & "; mkdir -p " & fldrScripts
	
	if ExistsFile("~/Library/'Application Scripts'/com.microsoft.Powerpoint/myScript.scpt") is false then
		tell application "Finder"
			--GET THE WORKING DIRECTORY FOR FILE COPY OF SCRIPT
			--get folder of (path to me) as Unicode text
			--set workingDir to POSIX path of result
			
			-- Get the path to the desktop folder
			set desktopDir to POSIX path of (path to desktop folder)
			
			--Write the new script in the current working directory
			set textFile to desktopDir & "myScript.scpt"
			
			--Delete script if it exists
			set posixPath to POSIX path of textFile as string
			do shell script "rm -rf \"" & posixPath & "\""
			
			--Create File and Folder Script Interface for Microsoft PowerPoint VBA Applications
			set fd to open for access textFile with write permission
			
			-- ExistsFile
			write "on ExistsFile(filePath)" & linefeed to fd as «class utf8» starting at eof
			write "tell application \"System Events\" to return (exists disk item filePath) and class of disk item filePath = file" & linefeed to fd as «class utf8» starting at eof
			write "end ExistsFile" & linefeed to fd as «class utf8» starting at eof
			close access fd
			
			-- Use Finder Duplicate command to create a copy of the script file in the target folder
			set fromPath to POSIX path of desktopDir & "myScript.scpt"
			set toPath to POSIX path of (path to library folder from user domain) & "Application Scripts/com.microsoft.Powerpoint"
			duplicate file (fromPath as POSIX file) to folder (toPath as POSIX file) with replacing
		end tell
	end if
	
	--Delete the temp script file from the working directory
	set posixPath to POSIX path of textFile as string
	do shell script "rm -rf \"" & posixPath & "\""
	
end CreateScriptsForVBA

-- ########### GLOBAL CONSTANTS #################
property DEBUG : false
property fldrScripts : "~/Library/'Application Scripts'/com.microsoft.Powerpoint"

-- ########### SET ACCORDING TO ADD-IN ############
property ADDIN_HOST : "mydomain.com" -- The host name of the server from which the add-in is to be downloaded
property ADDIN_FILE : "myAddIn.ppam" -- The full name of the PPAM file, including the extension
property ADDIN_NAME : "myAddIn" -- The name of the PPAM file, without the extension
property ADDIN_URL : "http://mydomain/downloads/myAddIn.ppam" -- The full URL to the PPAM file
property HELP_TIP : return & return & "Click the new tab in your ribbon." -- Optional help tip in the success dialog (set to "" if not using)

-- ########### ENTRY POINT #####################
tell application "Microsoft PowerPoint"
	display alert "PowerPoint Add-In Installer" message "This will install " & ADDIN_NAME & ". Continue?" buttons {"Yes", "No"}
	if button returned of result = "No" then error number -128 -- quit as "user cancelled"
end tell

-- Update the initial progress information
set progress total steps to 3
set progress completed steps to 0
set progress description to "Installing add-in."
set progress additional description to "Downloading..."

-- Download the PPAM file specified in the setup section above and save locally
DownloadAddIn()

set progress completed steps to 1
set progress additional description to "Registering..."

-- Attempt to register and load the add-in
set myAddIn to RegisterAddIn(GetHomeFolder() & "/Library/Group Containers/UBF8T346G9.Office/User Content.localized/Add-Ins/" & ADDIN_FILE)

set progress completed steps to 2
set progress additional description to "Validating..."

-- Read back the properties of the add-in
set {fClass, fFullName, fName, fPath, fRegistered, fAutoLoad, fLoaded, fRegiseterdHKLM} to splitText(properties of myAddIn, ",")

set progress completed steps to 3
set progress additional description to "Creating VBA scripts..."

CreateScriptsForVBA()

-- Reset the progress information
set progress total steps to 0
set progress completed steps to 0
set progress description to ""
set progress additional description to ""

-- Create a data folder in the Office sandbox for VBA to use
MakeDataFolder()

-- If the add-in is Registered, AutoLoad is on and it's Loaded, give user feedback
if fRegistered = true and fAutoLoad = true and fLoaded = true then
	tell application "Microsoft PowerPoint"
		display alert "Success!" message ADDIN_NAME & " for PowerPoint has been installed." & HELP_TIP as informational buttons {"OK"} -- giving up after 3
	end tell
end if